概述

一直以来，觉得MySQL中使用\G参数改变输出结果集的显示方式非常好用，尤其是在命令行界面。但是ORACLE数据库没有这个功能，今天在搜索到Tom大师的一篇博文时，发现大师用一个存储过程print_table实现了类似这样的功能。

print_table

建立存储过程如下：

CREATE OR REPLACE PROCEDURE print_table(p_query IN VARCHAR2) 
AUTHID CURRENT_USER 
IS 
 l_thecursor INTEGER DEFAULT dbms_sql.open_cursor; 
 l_columnvalue VARCHAR2(4000); 
 l_status INTEGER; 
 l_desctbl dbms_sql.desc_tab; 
 l_colcnt NUMBER; 
BEGIN 
 EXECUTE IMMEDIATE 'alter session set nls_date_format=''dd-mon-yyyy hh24:mi:ss'' '; 
 
 dbms_sql.parse(l_thecursor, p_query, dbms_sql.native); 
 
 dbms_sql.describe_columns (l_thecursor, l_colcnt, l_desctbl); 
 
 FOR i IN 1 .. l_colcnt LOOP 
 dbms_sql.define_column (l_thecursor, i, l_columnvalue, 4000); 
 END LOOP; 
 
 l_status := dbms_sql.EXECUTE(l_thecursor); 
 
 WHILE ( dbms_sql.Fetch_rows(l_thecursor) > 0 ) LOOP 
 FOR i IN 1 .. l_colcnt LOOP 
 dbms_sql.column_value (l_thecursor, i, l_columnvalue); 
 
 dbms_output.Put_line (RPAD(L_desctbl(i).col_name, 30) 
 || ': ' 
 || l_columnvalue); 
 END LOOP; 
 
 dbms_output.put_line('-----------------'); 
 END LOOP; 
 
 EXECUTE IMMEDIATE 'alter session set nls_date_format=''dd-MON-rr'' '; 
EXCEPTION 
 WHEN OTHERS THEN 
 EXECUTE IMMEDIATE 
 'alter session set nls_date_format=''dd-MON-rr'' '; 
 
 RAISE; 
END; 
/ 

测试如下：

SQL> set serveroutput on size 99999;
SQL> select userenv('sid') from dual; 
USERENV('SID')
--------------
	 350
SQL> execute print_table('select * from v$session where sid=350');

大家有空也可以测试一下，这个存储过程还是挺好用的。后面会分享更多devops和DBA方面的内容，感兴趣的朋友可以关注下！